@Matt: HA :-) Tough one, though, technically it's possible (most XSLT should work fine collapsed to a single line) but doesn't really count :-)

@Eric: Here's a "textbook" Muenchian Grouping example:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library"
>
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />

    <xsl:variable name="myNodes" select="umbraco.library:GetMedia(1216, true())/descendant-or-self::*[@nodeTypeAlias = 'File']" />

    <!-- Create a key (index) on File elements indexed by year -->
    <xsl:key name="file-by-year" match="*[@nodeTypeAlias = 'File']" use="substring(dateGenerated, 1, 4)" />

    <xsl:template match="/">
        <!-- This finds the first node in every year group -->
        <xsl:for-each select="$myNodes[count(. | key('file-by-year', substring(dateGenerated, 1, 4))[1]) = 1]">
            <xsl:sort select="dateGenerated" order="descending" />

            <!-- Process the once-per-group info (i.e., write the header) -->
            <xsl:apply-templates select="." mode="group" />

            <ul>
                <!-- Process each item in this group -->
                <xsl:apply-templates select="key('file-by-year', substring(dateGenerated, 1, 4))" mode="item">
                    <xsl:sort select="dateGenerated" order="descending" />
                </xsl:apply-templates>
            </ul>
        </xsl:for-each>
    </xsl:template>

    <!-- Output for group header (applied once per group) -->
    <xsl:template match="*[@nodeTypeAlias = 'File']" mode="group">
        <h2>
            <xsl:value-of select="substring(dateGenerated, 1, 4)" />
        </h2>
    </xsl:template>

    <!-- Output for each item in the group -->
    <xsl:template match="*[@nodeTypeAlias = 'File']" mode="item">
        <li>
            <a href="{umbracoFile}" title="{umbracoFile}" target="_blank">
                <xsl:value-of select="umbracoFile" />
            </a>
        </li>
    </xsl:template>

</xsl:stylesheet>

/Chriztian