Hi Jing,

Try this out - it's fairly self-explanatory and can be easily modified:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::*[@level = 1]" />

    <!-- You can also grab this by id if you want -->
    <xsl:variable name="news" select="$siteRoot/descendant-or-self::News" />

    <xsl:template match="/">
        <!-- Apply templates to every second article in "row" mode, starting with the first  -->
        <xsl:apply-templates select="$news/NewsArticle[position() mod 2 = 1]" mode="row" />
    </xsl:template>

    <!-- Template to start a row -->
    <xsl:template match="NewsArticle" mode="row">
        <div class="news-row">
            <!-- Now render this article and the following -->
            <xsl:apply-templates select=". | following-sibling::NewsArticle[1]" mode="cell" />
        </div>
    </xsl:template>

    <!-- Template for a News Article -->
    <xsl:template match="NewsArticle" mode="cell">
        <div class="news-cell">
            <a href="{umbraco.library:NiceUrl(@id)}">
                <xsl:value-of select="@nodeName" />
            </a>
        </div>
    </xsl:template>

</xsl:stylesheet>

/Chriztian