Any ideas?

Hi ds,

In my projects I usually have a macro called headContent, which starts out something like this:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::Website" />

    <xsl:template match="/">
        <!-- Recursively look for the Meta Page Title -->
        <xsl:apply-templates select="$currentPage/ancestor-or-self::*[normalize-space(metaPageTitle)][1]/metaPageTitle" />

        <!-- Do anything page-specific --> <xsl:apply-templates select="$currentPage" />
    </xsl:template>

    <!-- Frontpage -->
    <xsl:template match="Website">
        <!-- Put a comment in...  -->
        <xsl:comment>
            This page was developed by Blah for Foo...
        </xsl:comment>
    </xsl:template>

    <!-- Standard pages -->
    <xsl:template match="Textpage">
        <!-- Do something -->
    </xsl:template>

    <!-- Specific page - use id or name, whichever suits -->
    <xsl:template match="Textpage[@nodeName = 'Contact']">
        <script src="/scripts/contactValidationFTW.js"><xsl:comment /></script>
    </xsl:template>

    <!-- Page Title -->
    <xsl:template match="metaPageTitle">
        <title>
            <xsl:value-of select="." />
        </title>
    </xsl:template>

    <!-- Pages with no special action - no output -->
    <xsl:template match="*[@isDoc]" priority="-1" />

</xsl:stylesheet>

/Chriztian

Whoops - the "Do anything page-specific" comment was supposed to be *above* the apply-templates instruction. It doesn't change anything, but now it looks like you need to do something at that point. It's just explains what the following line does.

/Chriztian

Thanks for the feedback Chriztian,

I am not familiar with xslt much. Hence, I will look and try to do it cause it seems a bit advanced xslt.

Could you please firstly help with the following? Instead of for-each loop, how could I get only the title, description and image of current page ?

<xsl:for-each select="$umbraco.library:GetXmlNodeById('1078')/* [@isDoc and string(umbracoNaviHide) != '1']">
  <meta property="og:title" content="{newstitle}" />
  <meta property="og:description" content="{newsDescription}" />
  <meta property="og:image" content="{$SiteURL}{umbracoFile}" />
</xsl:for-each>

it outputs that;

<meta property="og:title" content="">
<meta property="og:description" content="Deneme">
<meta property="og:image" content="/media/469/19_mayis_kutlamasi.jpg">
<meta property="og:title" content="">
<meta property="og:description" content="Deneme">
<meta property="og:image" content="/media/528/klasik_otomobil_start.jpg">
<meta property="og:title" content="">
<meta property="og:description" content="Deneme2 ">
<meta property="og:image" content="/media/454/amesem_projesi.jpg">

Hi Chriztian,

That made the trick.

is working on a reply...