Hi David,

Create a Macro called "Navigation" - just use the "Clean" template.

Replace the XSLT generated with this and you're off to a good start:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::*[@level = 1]" />

    <xsl:template match="/">
        <ul id="mainMenu">
            <li><a href="/" title="Home">Home</a></li>
            <xsl:apply-templates select="$siteRoot/*[@isDoc][not(umbracoNaviHide = 1)]" />
        </ul>
    </xsl:template>

    <xsl:template match="*[@isDoc]">
        <xsl:variable name="childNodes" select="*[@isDoc][not(umbracoNaviHide = 1)]" />
        <li>
            <a href="{umb:NiceUrl(@id)}" title="{@nodeName}">
                <xsl:if test="$childNodes">
                    <xsl:attribute name="href">#</xsl:attribute><!-- Override href -->
                </xsl:if>
                <xsl:value-of select="@nodeName" />
            </a>
            <xsl:if test="$childNodes">
                <ul class="noJS">
                    <xsl:apply-templates select="$childNodes" />
                </ul>
            </xsl:if>
        </li>
    </xsl:template>

</xsl:stylesheet>

/Chriztian