Hi Alex,

This is not too hard, once you figure out what is supposed to happen - I hardly ever use "generic" systems for navigation because there's always something in the current project that isn't possible (or they have 5 times more code than necessar for the present problem). I took a quick look at your structure and desired output, and wrote this, to show how I'd approach that situation:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />

    <!-- Grab the first SiteHomepage upwards from the current page -->
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::SiteHomepage[1]" />

    <xsl:template match="/">
        <ul>
            <!-- Process the root and its children -->
            <xsl:apply-templates select="$siteRoot | $siteRoot/*[@isDoc]" />
        </ul>
    </xsl:template>

    <!-- Generral template for a document node -->
    <xsl:template match="*[@isDoc]">
        <li>
            <a href="{umb:NiceUrl(@id)}">
                <xsl:value-of select="@nodeName" />
            </a>
            <!-- If this is a Textpage and it has children of that type, generate a sub list -->
            <xsl:if test="self::Textpage/Textpage">
                <ul>
                    <xsl:apply-templates select="Textpage" />
                </ul>
            </xsl:if>
        </li>
    </xsl:template>

</xsl:stylesheet>

/Chriztian 

Thank you so much Chriztian!

My only issue is, when I include another SiteHomepage further *down* in the tree, it should appear as a link at the appropriate level - but its children should *not* appear.

In my example above, viewing page 1A should show the following subnavigation list:

- Site 1
- Page 1A
- Page 1B
- Site 1C

Using your XSL, it shows the following:

- Site 1
- Page 1A
- Page 1B

(Site 1C is absent). I'm guessing I need to alter this line:

<xsl:apply-templates select="$siteRoot | $siteRoot/*[@isDoc]" />

To include the SiteHomepage document type in the conditions? 

Hi Alex,

That's strange, because it does the right thing in my setup - I checked the three examples you provided.

You shouldn't need to change that line - it takes the root (found by going up recursively to find the first SiteHomepage) and its children (of any Document Type) and sends them away for processing.

In the processing template, we only list childnodes if the current node is a Textpage document (or whatever you've renamed it to), but as long as the SiteHomepage for Site 1C is a childnode of Site 1, it'll be processed by the template (but won't have its children processed).

Is there anything else in your setup that could interfere with this?

/Chriztian

Ah, apparently I was looking at the wrong node in my test example! Forehead slap.

Things are working well with one small problem... all nodes are displayed within the siteRoot delimiters. I now need to add the "exploding" functionality that is common to so many nav functions. Right now, Page 2AA is visible in the tree when the user is viewing Site2 or Page 2B. It should be hidden until the user visits Page2A (or Page2AA).

Here's my macro for reference. I've made some additional modifications to add whitespace and some special characters and classes I'm using. Also I had to edit the line <xsl:apply-templates select="$siteRoot | $siteRoot/*[@isDoc]" />; it was ignoring the sort order and always putting SiteRoots at a fixed position.

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [
    <!ENTITY nbsp "&#x00A0;">
    <!ENTITY rarr "&#x2192;">
]>
<xsl:stylesheet
        version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:umb="urn:umbraco.library"
        exclude-result-prefixes="umb">

    <xsl:output method="html" omit-xml-declaration="yes"/>

    <xsl:param name="currentPage" />

    <!-- Grab the first SiteHomepage upwards from the current page -->
    <!-- Thanks to Chriztian Steinmeier on the Umbraco forums -->
    <!-- http://our.umbraco.org/forum/developers/xslt/29195-Subnavigation-from-a-root-defined-by-document-type -->

    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::SiteHomepage[1]" />
    <xsl:template match="/">

        <nav class="subnav">
            <xsl:text>&#xa;</xsl:text> <!-- newline -->
            <ul>
                <!-- Process the root -->
                <xsl:apply-templates select="$siteRoot" />
                <!-- Process its children -->
                <xsl:apply-templates select="$siteRoot/*[@isDoc]">
                    <xsl:sort select="@sortOrder" order="ascending" data-type="number" />
                </xsl:apply-templates>
            </ul>
            <xsl:text>&#xa;</xsl:text> <!-- newline -->
        </nav>
    </xsl:template>

    <!-- General template for a document node -->
    <xsl:template match="*[@isDoc]">

        <xsl:choose>
            <!-- Did the user specifiy *not* to display this node? -->
            <xsl:when test="string(umbracoNaviHide) != '1'">

                <!-- Is the node selected? -->
                <xsl:variable name="isSelected">
                    <xsl:if test="$currentPage/@id = @id">selected</xsl:if>
                </xsl:variable>

                <li class="{$isSelected}">
                    <a href="{umb:NiceUrl(@id)}">

                        <!-- Set the innerText for the a element -->
                        <xsl:value-of select="./pageTitle/text()"/>
                        <xsl:if test="string(./pageTitle/text()) = ''">
                            <xsl:value-of select="@nodeName"/>
                        </xsl:if>

                        <!-- Add &rarr; character to current page -->
                        <xsl:if test="string($isSelected) = 'selected'"> &rarr;</xsl:if>
                    </a>

                    <!-- Generate a sub list -->
                    <xsl:if test="self::SitePage/SitePage">
                        <xsl:text>&#xa;</xsl:text> <!-- newline -->
                        <ul>
                            <xsl:apply-templates select="SitePage" />
                        </ul>
                    </xsl:if>
                </li>
            </xsl:when>

            <!-- Need to leave this blank -->
            <xsl:otherwise></xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

Chriztian,

You are great. Thanks so much for your help!

I did follow your advice and shorten the logic quite a bit. I was actually aware that I was doing things heavy-handedly, in particular I wanted to eliminate that <xsl:choose> bit regarding umbracoNaviHide, I just couldn't figure out where to put the condition (or the logical syntax, frankly).

Karma given and I am now following your Twitter. :)

is working on a reply...