Hi ashwini,

This happens because the navigation looks for the ancestor at level 1 to be the root of the menu (which normally is the case - many Umbraco sites have a single root node containing the site nodes) - but when you're in the news section it'll obviously find the "### News" node instead - the trick here is to make sure to find the correct top node, which you can do by going all the way to the <root> element first, and then selecting the "Simple website" node relative to that instead. It also makes everything much easier to read (and modify):

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
<!-- Go all the way up to the <root> containg everything --> <xsl:variable name="absoluteRoot" select="$currentPage/ancestor::root" />

    <!-- You can do this one by @id too, if you want e.g.: $absoluteRoot/*[@id = 1234] -->
    <xsl:variable name="simpleSiteRoot" select="$absoluteRoot/*[@nodeName = 'Simple website']" />

    <xsl:template match="/">
        <ul id="topNavigation">
            <li class="home">
                <xsl:if test="$currentPage/@id = $simpleSiteRoot/@id">
                    <xsl:attribute name="class">home current</xsl:attribute>
                </xsl:if>
                <a href="/">Home</a>
            </li>
            <xsl:for-each select="$simpleSiteRoot/*[@isDoc][not(umbracoNaviHide = 1)]">
                <li>
                    <a class="navigation" href="{umbraco.library:NiceUrl(@id)}">
                        <span><xsl:value-of select="@nodeName" /></span>
                    </a>
                </li> 
            </xsl:for-each>
        </ul>
    </xsl:template>

</xsl:stylesheet>

/Chriztian