Hi Yael,

You should be able to do what you want, though it'll take a little more work... here's how to do it:

<xsl:for-each select="umbraco.library:GetXmlNodeById(1473)//*[@isDoc][not(umbracoNaviHide = 1)][not(self::RelatedFile)]">
    <li>
        <div class="folio-thumb">
            <a class="">
                <xsl:apply-templates select="link" />
                <img class="" src="{listItemImg}" alt="{listItemImgAlt}" title="{listItemImgTitle}" />
            </a>
        </div>
        <h5>
            <a class="">
                <xsl:apply-templates select="link" />
                <xsl:value-of select="listItemTitle" disable-output-escaping="yes" />
            </a>
        </h5>
        <a class="Quick-Pick-Text">
            <xsl:apply-templates select="link" />
            <xsl:value-of select="listItemText" disable-output-escaping="yes" />
        </a>
    </li>
</xsl:for-each>

<xsl:template match="link">
    <!-- Make sure a link was picked -->
    <xsl:if test="normalize-space(.)">
        <!-- Grab the actual node -->
        <xsl:variable name="node" select="umbraco.library:GetXmlNodeById(.)" />
        <xsl:attribute name="href">
            <xsl:choose>
                <!-- If it has an alias assigned, use that -->
                <xsl:when test="normalize-space($node/umbracoUrlAlias)">
                    <xsl:value-of select="concat('/', $node/umbracoUrlAlias)" />
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="umbraco.library:NiceUrl(.)" />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </xsl:if>
</xsl:template>

Please note that this does not take multiple URL aliases into account (you'd need to grab the first if you're using multiple aliases).

You'll also need to add '.aspx' to the concat() if you're not using directory URLs (which you should :-)

/Chriztian