After two days of heartbreak i figured it out :-) You gave me some insight to how XSLT works. Thanks for that :-)

No problem :) glad i could help.  What was the solution in the end?  Thanks :) Charles.

Here is my end code :-)

Had to change some of the levels as I wasn't thinking clearly when i asked the question :-)

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ <!ENTITY nbsp "&#x00A0;"> ]>
<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxml="urn:schemas-microsoft-com:xslt"
  xmlns:umbraco.library="urn:umbraco.library" xmlns:Exslt.ExsltCommon="urn:Exslt.ExsltCommon" xmlns:Exslt.ExsltDatesAndTimes="urn:Exslt.ExsltDatesAndTimes" xmlns:Exslt.ExsltMath="urn:Exslt.ExsltMath" xmlns:Exslt.ExsltRegularExpressions="urn:Exslt.ExsltRegularExpressions" xmlns:Exslt.ExsltStrings="urn:Exslt.ExsltStrings" xmlns:Exslt.ExsltSets="urn:Exslt.ExsltSets" xmlns:PS.XSLTsearch="urn:PS.XSLTsearch"
  exclude-result-prefixes="msxml umbraco.library Exslt.ExsltCommon Exslt.ExsltDatesAndTimes Exslt.ExsltMath Exslt.ExsltRegularExpressions Exslt.ExsltStrings Exslt.ExsltSets PS.XSLTsearch ">

<xsl:output method="xml" omit-xml-declaration="yes"/>

<xsl:param name="currentPage"/>

<!-- update this variable on how deep your site map should be -->
<xsl:variable name="maxLevelForSitemap" select="8"/>

<xsl:template match="/">
<div id="sitemap">
  <xsl:call-template name="topNode">  
  </xsl:call-template>
<xsl:call-template name="drawNodes">  
<xsl:with-param name="parent" select="$currentPage/ancestor-or-self::* [@isDoc and @level=1]"/>  
</xsl:call-template>
</div>
</xsl:template>

    <xsl:template name="topNode">
<ul>
  <li>
    <a href="/">Home</a>
  </li>
</ul>
    </xsl:template>
<xsl:template name="drawNodes">
<xsl:param name="parent"/>
  <xsl:if test="umbraco.library:IsProtected($parent/@id, $parent/@path) = 0 or (umbraco.library:IsProtected($parent/@id, $parent/@path) = 1 and umbraco.library:IsLoggedOn() = 1)">
<ul>
  <xsl:for-each select="$parent/* [@isDoc and string(umbracoNaviHide) != '1' and @level &lt;= $maxLevelForSitemap]">
    <xsl:choose>
      <xsl:when test="@level &lt; 4">
        <li>  
          <xsl:value-of select="@nodeName"/>
          <xsl:if test="count(./* [@isDoc and string(umbracoNaviHide) != '1' and @level &lt;= $maxLevelForSitemap]) &gt; 0">   
            <xsl:call-template name="drawNodes">    
              <xsl:with-param name="parent" select="."/>    
            </xsl:call-template>  
          </xsl:if> 
        </li>
      </xsl:when>
      <xsl:when test="@level &gt;=4"> 
        <li>
          <a href="{umbraco.library:NiceUrl(@id)}">
          <xsl:value-of select="@nodeName"/></a>  
          <xsl:if test="count(./* [@isDoc and string(umbracoNaviHide) != '1' and @level &lt;= $maxLevelForSitemap]) &gt; 0">   
            <xsl:call-template name="drawNodes">    
              <xsl:with-param name="parent" select="."/>    
            </xsl:call-template>  
          </xsl:if>
        </li>
      </xsl:when>
    </xsl:choose>
  </xsl:for-each>
    </ul>
    </xsl:if>

</xsl:template>
</xsl:stylesheet>

Brilliant :) well hope i helped a bit :D.  Charles

Hi Jimmy & Charles,

Just for reference, here's my "match templates" approach to something like this (note that it's a quite different way of thinking):

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::*[@level = 1]" />

    <xsl:variable name="maxLevelForSiteMap" select="8" />
    <xsl:variable name="isLoggedOn" select="umb:IsLoggedOn()" />

    <xsl:template match="/">
        <div id="sitemap">
            <xsl:call-template name="topNode" />
            <xsl:apply-templates select="$siteRoot" />
        </div>
    </xsl:template>

    <xsl:template match="*[@isDoc]">
        <xsl:variable name="isProtected" select="umb:IsProtected(@id, @path)" />
        <xsl:if test="not($isProtected) or ($isProtected and $isLoggedOn)">
            <ul>
                <xsl:apply-templates select="*[@isDoc][@level &lt;= $maxLevelForSiteMap][not(umbracoNaviHide = 1)]" mode="link" />
            </ul>
        </xsl:if>
    </xsl:template>

    <!-- General template for links -->
    <xsl:template match="*[@isDoc]" mode="link">
        <xsl:variable name="subNodes" select="*[@isDoc][@level &lt;= $maxLevelForSiteMap][not(umbracoNaviHide = 1)]" />
        <li>
            <a href="{umb:NiceUrl(@id)}">
                <xsl:value-of select="@nodeName" />
            </a>
            <xsl:apply-templates select="*[@isDoc][@level &lt;= $maxLevelForSiteMap][not(umbracoNaviHide = 1)]" />
        </li>
    </xsl:template>

    <!-- Exclude link for levels 1 through 3 -->
    <xsl:template match="*[@isDoc][@level &lt; 4]" mode="link">
        <li>
            <xsl:value-of select="@nodeName" />
            <xsl:apply-templates select="*[@isDoc][@level &lt;= $maxLevelForSiteMap][not(umbracoNaviHide = 1)]" />
        </li>
    </xsl:template>

    <!-- Special template to render Home node -->
    <xsl:template name="topNode">
        <ul>
            <li><a href="/">Home</a></li>
        </ul>
    </xsl:template>

</xsl:stylesheet>

/Chriztian

Thanks Chriztian :).  Out of intrest why have you got a a template topNode just to put a <ul> <li></li></ul> in or i am missing something?  Thanks.  Charlie.

Hi Charlie,

Mostly because it makes it more obvious that it's actually getting a special treatment (URL is almost never the NiceUrl() result, nor is its name "Home" - in my solutions :-)

For the record, in my own solutions the "Home" node is always a document type called Website, and I just have a match template for that instead.

/Chriztian 

ahhhh ok :)  just looking at that code i find it really hard to quicky see what its doing becuase its so seperated.  ok :)  we always have document types of HTML and then Default and then put all of the header information in the HTML template.

How come you dont use NiceUrl()?

Charlie.

The overview thing is because you're still "thinking" in C# (or other "regular" programming language) terms — XSLT really works much more like CSS in many ways, but, unfortunately, xsl:for-each and xsl:choose tricks a lot of developers into thinking it's just another programming language :-)

I *do* use NiceUrl() - but not on the Home node, because I want the link to say href="/" - NiceUrl() will give me something like href="/ikea-dk" or similar.

/Chriztian

What is the 'overview' thing?  In any language you need people looking at the code to quickly understand whats going on, it just appears to add complexity.  Thanks for the tip of not using the NiceUrl() in the home node, will bear that in mind :).  Thanks.  Charles.

is working on a reply...