Thanks Chriztian,

That was spot on and I've done my house keeping, a couple of nice tips thanks.

Must say I'm really liking the flexibility of Umbraco especially for a front end guy like me.

Still stuck with the my second issue now I have all the values in the table I need to sort the data and put the club with the most points at the top and descending down.

I've spent some time searching and can see that you can't use a variable i.e $points, <xsl:sort select="$points" order="descending"/>, do you have any clue how this could be done or a similar post that could help?

Kind Regards,

Kyle

Hi Kyle,

So you could extract all the variables back into a giant sort selection that didn't use variables, but it would be hard to read and understand before you'd have finished the rest of the site - so here's a better/nicer approach:

When dealing with large sets of data like that, it can be much more efficient to simply pre-calculate the results and create an XML variable with those, and use that instead for rendering the table - e.g., having something like this (for every team):

<result club="1337" name="Liverpool Rangers">
    <played>13</played>

    <homeWins>3</homeWins>
    <homeDraws>2</homeDraws>
    <homeLose>1</homeLose>

    <awayWins>7</awayWins>
    <awayDraws>0</awayDraws>
    <awayLose>0</awayLose>

    <totalWins>10</totalWins>
    <totalDraws>2</totalDraws>
    <totalLose>1</totalLose>

    <goalsFor>12</goalsFor>
    <goalsAgainst>3</goalsAgainst>
    <goalsDiff>9</goalsDiff>

    <points>32</points>
</result>

As you can see, it should then be easy as pie to sort on any of all those bits (though you'd probably be better off using some sort of "sortable table" JS plugin for that).

Here's a crude version of how you'd do something like the above:

<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />

    <!-- Index the published resultnodes by team for speedy lookup -->
    <xsl:key name="homeGamesForTeam" match="FixtureOrResult[publishResult = 1]" use="homeTeam" />
    <xsl:key name="awayGamesForTeam" match="FixtureOrResult[publishResult = 1]" use="awayTeam" />

    <xsl:variable name="$Source" select="umbraco.library:GetXmlNodeById($currentPage/selectedNode)/Clubs" />

    <xsl:template match="/">
        <!-- Process the Clubs node in the selected section -->
        <xsl:apply-templates select="$Source" />
    </xsl:template>

    <!-- Template for the Clubs node -->
    <xsl:template match="Clubs">
        <xsl:variable name="resultsProxy">
            <!-- Run through all the teams -->
            <xsl:for-each select="Club">
                <!-- Scope these to the current team to reduce number of nodes searched -->
                <xsl:variable name="homeGames" select="key('homeGamesForTeam', @id)" />
                <xsl:variable name="awayGames" select="key('awayGamesForTeam', @id)" />

                <!-- Collect all the results -->
                <xsl:variable name="homeWins"  select="count($homeGames[homeTeamGoals &gt; awayTeamGoals])"/>
                <xsl:variable name="homeDraws" select="count($homeGames[homeTeamGoals = awayTeamGoals])"/>
                <xsl:variable name="homeLose"  select="count($homeGames[homeTeamGoals &lt; awayTeamGoals])"/>
                <!-- Away Games -->
                <xsl:variable name="awayWins"  select="count($awayGames [homeTeamGoals &lt; awayTeamGoals])"/>
                <xsl:variable name="awayDraws" select="count($awayGames [homeTeamGoals = awayTeamGoals])"/>
                <xsl:variable name="awayLose"  select="count($awayGames [homeTeamGoals &gt; awayTeamGoals])"/>
                <!-- Totals -->
                <xsl:variable name="totalWins"  select="$homeWins + $awayWins"/>
                <xsl:variable name="totalDraws" select="$homeDraws + $awayDraws"/>
                <xsl:variable name="totalLose"  select="$homeLose + $awayLose"/>
                <!-- Goals -->
                <xsl:variable name="goalsFor"     select="sum($homeGames/homeTeamGoals | $awayGames/homeTeamGoals)"/>
                <xsl:variable name="goalsAgainst" select="sum($homeGames/awayTeamGoals | $awayTeamGoals/awayTeamGoals)"/>
                <xsl:variable name="goalsDiff"    select="$goalsFor - $goalsAgainst"/>
                <!-- Points -->
                <xsl:variable name="points" select="($totalWins * 3) + ($totalDraws)"/>

                <!-- Wrap everything in a precalculated <result> for this team -->
                <result club="{@id}" name="{@nodeName}">
                    <played><xsl:value-of select="count($homeGames | $awayGames)"/></played>

                    <homeWins><xsl:value-of  select="$homeWins" /></homeWins>
                    <homeDraws><xsl:value-of select="$homeDraws" /></homeDraws>
                    <homeLose><xsl:value-of  select="$homeLose" /></homeLose>

                    <awayWins><xsl:value-of  select="$awayWins" /></awayWins>
                    <awayDraws><xsl:value-of select="$awayDraws" /></awayDraws>
                    <awayLose><xsl:value-of  select="$awayLose" /></awayLose>

                    <totalWins><xsl:value-of select="$homeWins + $awayWins" /></totalWins>
                    <totalDraws><xsl:value-of select="$homeDraws + $awayDraws" /></totalDraws>
                    <totalLose><xsl:value-of select="$homeLose + $awayLose" /></totalLose>

                    <goalsFor><xsl:value-of select="$goalsFor" /></goalsFor>
                    <goalsAgainst><xsl:value-of select="$goalsAgainst" /></goalsAgainst>
                    <goalsDiff><xsl:value-of select="$goalsDiff" /></goalsDiff>

                    <points><xsl:value-of select="$points" /></points>
                </result>
            </xsl:for-each>
        </xsl:variable>
        <!-- (This is needed to get an "XPath-navigable" variable) -->
        <xsl:variable name="results" select="make:node-set($resultsProxy)/result" />

        <!-- Output table of results -->
        <table>
            <tr>
                <th>Team</th>
                <th>Played</th>
                <th>HW</th>
                <th>HD</th>
                <th>HL</th>
                <th>AW</th>
                <th>AD</th>
                <th>AL</th>
                <th>W</th>
                <th>D</th>
                <th>L</th>
                <th>GF</th>
                <th>GA</th>
                <th>GD</th>
                <th>Pts</th>
            </tr>

            <!-- Run through the results, sorted backwards by points scored -->
            <xsl:apply-templates select="$results">
                <xsl:sort select="points" data-type="number" order="descending" />
            </xsl:apply-templates>
        </table>
    </xsl:template>

    <!-- Template for a single <result> -->
    <xsl:template match="result">
        <!-- Just pick the pre-calculated results one by one -->
        <tr>
            <td><xsl:value-of select="@name" /></td>
            <td><xsl:value-of select="played" /></td>
            <td><xsl:value-of select="homeWins" /></td>
            <td><xsl:value-of select="homeDraws" /></td>
            <td><xsl:value-of select="homeLose" /></td>
            <!-- etc. -->
        </tr>
    </xsl:template>

</xsl:stylesheet>

/Chriztian

Hi Chriztian,

Thanks again, a minor tweak and it worked a treat. Another really handy method.

I changed the "make:"

<xsl:variable name="results" select="make:node-set($resultsProxy)/result" />

To

<xsl:variable name="results" select="msxml:node-set($resultsProxy)/result" />

Kind Regards,

Kyle

Hi Kyle,

Ha :) Good catch - I do forget to change that, from time to time :-)

/Chriztian

is working on a reply...