Hi Crawn,

There are lots of ways to so that better - here's one using a couple of XSLT templates:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library"
>

    <xsl:output method="html" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::*[@level = 1]" />

    <xsl:template match="/">
        <div id="Images">
            <!-- Process all `itemPicN` properties that have a value stored -->
            <xsl:apply-templates select="$currentPage/*[starts-with(name(), 'itemPic')][normalize-space()]" mode="image" />
        </div>
    </xsl:template>

    <!-- Catch-all for the itemPicN properties -->
    <xsl:template match="*" mode="image">
        <xsl:variable name="mediaNode" select="umbraco.library:GetMedia(., false())" />
        <xsl:if test="not($mediaNode[error])">
            <xsl:apply-templates select="$mediaNode" />
        </xsl:if>
    </xsl:template>

    <!-- Template for an Image -->
    <xsl:template match="Image">
        <a href="{umbracoFile}" title="{umbracoFile}">
            <img src="{umbracoFile}" border="0" alt="{@nodeName}" />
        </a>
    </xsl:template>

    <!-- Example of another media type -->
    <xsl:template match="PDFfile">
        <a href="{umbracoFile}" type="application/pdf"><xsl:value-of select="@nodeName" /> (PDF)</a>
    </xsl:template>

</xsl:stylesheet>

/Chriztian