Sorting and especially grouping is worse in xslt 1.0, in this cases I would recommend doing an own xslt-extension using the umbraco.presentation.nodefactory.node which creates you the sorted list. I can give you an example tomorrow.

Thomas

Hi Garrett,

Here's a example of how it could be done with XSLT, hopefully the comments are sufficient help - otherwise feel free to ask about what's happening:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common"
>
    <xsl:param name="currentPage" />

    <xsl:variable name="root" select="$currentPage/ancestor-or-self::root" />

    <xsl:variable name="news" select="$root//node[../@nodeTypeAlias = 'Newsroom']" />
    <xsl:variable name="press" select="$root//node[../@nodeTypeAlias = 'Press Releases']" />

    <!-- Number of recent items wanted -->
    <xsl:variable name="itemsToShow" select="5" />

    <!-- Sort and reject -->
    <xsl:variable name="newsSorted">
        <xsl:for-each select="$news">
            <!-- Sort using createDate - use whatever fits  -->
            <xsl:sort select="@createDate" data-type="text" order="descending" />
            <xsl:if test="position() &lt;= $itemsToShow">
                <xsl:copy-of select="." />
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>

    <!-- Sort and reject -->
    <xsl:variable name="pressSorted">
        <xsl:for-each select="$press">
            <xsl:sort select="@createDate" data-type="text" order="descending" />
            <xsl:if test="position() &lt;= $itemsToShow">
                <xsl:copy-of select="." />
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>

    <!-- Here we go  -->
    <xsl:template match="/">
        <xsl:for-each select="exslt:node-set($newsSorted)/node">
            <xsl:variable name="pos" select="position()" />

            <!-- Render News item -->
            <xsl:apply-templates select="." />

            <!-- Render Press Release -->
            <xsl:apply-templates select="exslt:node-set($pressSorted)/node[$pos]" />
        </xsl:for-each>
    </xsl:template>

    <!-- Template for output of the node elements -->
    <xsl:template match="node">
        <p>
            <xsl:value-of select="@nodeName" />
        </p>
    </xsl:template>

</xsl:stylesheet>

/Chriztian

Wow, I really appreciate your attention (and generosity!).  I've applied your code to my XSLT file, and am gettnig the followiong error:

System.Xml.Xsl.XslLoadException: Prefix 'exslt' is not defined. An error occurred at c:\inetpub\wwwroot\xslt\633935434871394745_temp.xslt(45,4).

Any ideas?

Thanks again,

Garrett

You're welcome :-)

OK, easiest fix for this is probably to find the 2 calls to exslt:node-set in the XSLT file, and replace them with msxml:node-set, if you're using one of the standard XSLT files supplied by Umbraco.

Otherwise, let me know and I'll provide a full refund with an explanation :-)

/Chriztian

After some research, I've managed to get rid of this error by adding:

xmlns:exslt="http://exslt.org/common"

The output of the stylesheet, however, is empty:

<!--  -->       
<!-- #headlines -->

How do I translate this XSLT file into the template itself?  Should I be calling a Macro which uses this file?  If so, what type of Macro is it (List subpages from a changeable source, etc.)? 

Thanks again,

Garrett

They do.  The nodeTypeAliases are correct (News and PressReleases).  These nodeTypeAliases should be the node types of the Parent pages whose Children I want to get, right? Or the node type of the Children themselves?

I have changed the exslt: references to msxml:.  But neither scenario above outputs anything. YET ;)  I'll paste in my entire XSLT file here:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ <!ENTITY nbsp "&#x00A0;"> ]>
<xsl:stylesheet 
   version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
 xmlns:msxml="urn:schemas-microsoft-com:xslt"
  xmlns:umbraco.library="urn:umbraco.library" xmlns:Exslt.ExsltCommon="urn:Exslt.ExsltCommon" xmlns:Exslt.ExsltDatesAndTimes="urn:Exslt.ExsltDatesAndTimes" xmlns:Exslt.ExsltMath="urn:Exslt.ExsltMath" xmlns:Exslt.ExsltRegularExpressions="urn:Exslt.ExsltRegularExpressions" xmlns:Exslt.ExsltStrings="urn:Exslt.ExsltStrings" xmlns:Exslt.ExsltSets="urn:Exslt.ExsltSets" xmlns:tagsLib="urn:tagsLib" xmlns:BlogLibrary="urn:BlogLibrary" 
  exclude-result-prefixes="msxml umbraco.library Exslt.ExsltCommon Exslt.ExsltDatesAndTimes Exslt.ExsltMath Exslt.ExsltRegularExpressions Exslt.ExsltStrings Exslt.ExsltSets tagsLib BlogLibrary ">

    <xsl:output method="xml" omit-xml-declaration="yes" />

    <xsl:param name="currentPage"/>

   <xsl:variable name="root" select="$currentPage/ancestor-or-self::root" />
        
 <xsl:variable name="news" select="$root//node[../@nodeTypeAlias = 'News']" />
   <xsl:variable name="press" select="$root//node[../@nodeTypeAlias = 'PressReleases']" />
 
   <!-- Number of recent items wanted -->
  <xsl:variable name="itemsToShow" select="5" />
 
   <!-- Sort and reject -->
    <xsl:variable name="newsSorted">
            <xsl:for-each select="$news">
                   <!-- Sort using createDate - use whatever fits  -->
                     <xsl:sort select="@createDate" data-type="text" order="descending" />
                   <xsl:if test="position() &lt;= $itemsToShow">
                           <xsl:copy-of select="." />
                  </xsl:if>
           </xsl:for-each>
     </xsl:variable>
    
   <!-- Sort and reject -->
    <xsl:variable name="pressSorted">
           <xsl:for-each select="$press">
                  <xsl:sort select="@createDate" data-type="text" order="descending" />
                   <xsl:if test="position() &lt;= $itemsToShow">
                           <xsl:copy-of select="." />
                  </xsl:if>
           </xsl:for-each>
     </xsl:variable>

   <!-- Here we go  -->
    <xsl:template match="/">
       <xsl:for-each select="msxml:node-set($newsSorted)/node">  
          <xsl:variable name="pos" select="position()" />
                  
             <!-- Render News item -->
               <xsl:apply-templates select="." />
                   
             <!-- Render Press Release -->
               <xsl:apply-templates select="msxml:node-set($pressSorted)/node[$pos]" />
                
      </xsl:for-each>
  </xsl:template>
     
  <!-- Template for output of the node elements -->
   <xsl:template match="node">
        <p>
         <xsl:value-of select="@nodeName" />
     </p>
     </xsl:template>


</xsl:stylesheet>

What do you think my problem is here?

//Garrett

FYI, this is going to go on the Home Page, so the structure is as follows:

Home

   > Newsroom

        >> News

        >> Press Releases

Understood?  So I'm not sure the ancestor-or-self call is exactly what I want here as the root.  Is this looking at the tree recursively?

//Garrett

When I put the textareas in:

        <!-- Here we go  -->
    <xsl:template match="/">
    
     <textarea rows="8" cols="40"><xsl:copy-of select="$news" /></textarea>
      <textarea rows="8" cols="40"><xsl:copy-of select="$press" /></textarea>
         
      <xsl:for-each select="msxml:node-set($newsSorted)/node">  
          <xsl:variable name="pos" select="position()" />
                  
             <!-- Render News item -->
               <xsl:apply-templates select="." />
                   
             <!-- Render Press Release -->
               <xsl:apply-templates select="msxml:node-set($pressSorted)/node[$pos]" />
                
      </xsl:for-each>
  </xsl:template>

I get very strange behavior.  Whatever HTML comes after this in the Master template is CONTAINED IN the textarea.  And still no News items or Press Release items.  Just to be clear, again, the nodeTypeAliases are correct (News and PressReleases), assuming that hese nodeTypeAliases should be the node types of the PARENT pages whose Children I want to get, right? Or should they be the node types of the Children themselves?  Not that this works either, because it doesn't.  So in your test, you have Children under CWS_Gallery and News/Events and you are seeing them running this XSLT?  I don't know how.  I can't fugure out what is different between what we're doing.  How can I see if

<xsl:variable name="press" select="$root//node[../@nodeTypeAlias = 'PressReleases']" />

Has any meaning?

The reason the HTML gets caught in the textarea(s) is because the $press and $news are empty - so they're not catching anything.

Yes, the aliases are PARENT pages.

Yes, I get the expected behaviour on the CWS test.

Try to dump the complete XML (copy-of select="$root") in the textarea and make sure that the childnodes you expect to appear are indeed present (published) and children of said nodeTypes.

/Chriztian 

Chriztian-- I'm getting somewhere now, thanks to your (../@id = '1096']) hint!

I ended up having to use ID's instead of nodeTypeAliases. For some reason, these just weren't working....  By the way, this is VERY good code, and I expect to reuse it-- thanks very much for showing me the msxml:node-set method.  It's very powerful.

So, I am getting One News, One Press Release, One News, One Press Release, One News, One Press Release, etc.  This is exactly what I wanted.  Thanks again!

//Garrett

You're welcome Garrett, anytime...

/Chriztian 

is working on a reply...