Hi Andy,

As is usually the case, there's more than one way to implement such a feature.
Are you using the Unique Keyword for anything else (i.e., could you just use a page's ID in the Send to pages field)?

Anyways—here's a simple macro to help you get started:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:param name="currentPage" />

    <!-- Grab the "Home" node -->
    <xsl:variable name="siteRoot" select="$currentPage/ancestor-or-self::*[@level = 1]" />

    <xsl:template match="/">
        <!-- Grab all pages that have the current page's `uniqueKeyword` in their `sendToPages` property -->
        <xsl:variable name="relatedPages" select="$siteRoot//*[@isDoc][umb:Split(sendToPages, ' ')/value = $currentPage/uniqueKeyword]" />

        <section class="related">
            <xsl:apply-templates select="$relatedPages" />
        </section>

    </xsl:template>

    <!-- Template for a related page -->
    <xsl:template match="*[@isDoc]">
        <p>
            <xsl:value-of select="@nodeName" />
        </p>
    </xsl:template>

</xsl:stylesheet>

Please note a couple of things:

• uniqueKeyword and sendToPages are the aliases of the properties you've created - you may need to change these (case-sensitive, etc.)
• I'm assuming you're just using a space between the keywords in the sendToPages property - if you're using commas or another character, you need to change that in the call to the Split() function.

Hope that helps,

/Chriztian

This is great thanks for your help. So currentPage is a predefined parameter similar to umbracoNaviHide? I could see it being declared everywhere but I couldnt see it being set.

Thanks for your quick response!

Andy

is working on a reply...