Try putting the url in single quotes?

<xsl:variable name="" select="'http://api...photoset.gne'" />

Matt

Thank you Matt that helped, but now I don't get an error, but I also don't get any results back. Here is the XSLT my colleague wrote:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ 
  <!ENTITY nbsp "&#x00A0;"> 
<!ENTITY amp  "&#38;">
]>
<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxml="urn:schemas-microsoft-com:xslt"
  xmlns:umbraco.library="urn:umbraco.library"
  xmlns:media="http://search.yahoo.com/mrss"
  exclude-result-prefixes="msxml umbraco.library media">
<xsl:output method="xml" omit-xml-declaration="yes"/>
<!-- macroparameter with the url of the flickr
xmlfeed -->
<!--<xsl:variable name="url"
select="/macro/url" />-->
  <xsl:variable name="url" select="'http://api.flickr.com/services/feeds/photoset.gne?set=72157624035183498&amp;nsid=42415310@N08&amp;lang=en-us'" /> 
  <xsl:template match="/">
<xsl:if test="$url != ''">
  <!--
  fetch xmlsource from url - we are unable to use
select=document($url)
  but umbraco has a static function library available in xsl where
there exists a
  method of fetching a xmldocument given an url  -->
  <xsl:variable name="flickrxml" select="umbraco.library:GetXmlDocumentByUrl($url)" />
  <ul>
    <xsl:apply-templates select="$flickrxml//item" />
  </ul>
</xsl:if>
</xsl:template>
<xsl:template match="item">
  <li>
    <a href="{link}" title="{title}"><img src="{media:thumbnail/@url}"
alt="{title}"/></a>
  </li>
</xsl:template>
</xsl:stylesheet>

Couple of things.

1) The XML seems to be a different format from what you are expecting, ie nodes are called entry with different attributes so i'm guessing it's changed since the demo you are following.

2) You need to include the atom namespace so that you can access the nodes and attributes

Try the following:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ <!ENTITY nbsp "&#x00A0;"> ]>
<xsl:stylesheet 
 version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
 xmlns:msxml="urn:schemas-microsoft-com:xslt"
 xmlns:umbraco.library="urn:umbraco.library"
 xmlns:CommerceLibrary="urn:CommerceLibrary"
 xmlns:atom="http://www.w3.org/2005/Atom"
 exclude-result-prefixes="msxml umbraco.library CommerceLibrary atom">


 
<xsl:output method="xml" omit-xml-declaration="yes"/>
 
<xsl:variable name="url" select="'http://api.flickr.com/services/feeds/photoset.gne?set=72157624035183498&amp;nsid=42415310@N08&amp;lang=en-us'" />
<xsl:template match="/">
  <xsl:if test="$url != ''">
    <xsl:variable name="flickrxml" select="umbraco.library:GetXmlDocumentByUrl($url)" />
    <ul>
 <xsl:for-each select="$flickrxml//atom:entry">
  <li> <a href="{atom:link[@rel='alternate']/@href}" title="{atom:title}"><img src="{atom:link[@rel='enclosure']/@href}" alt="{atom:title}"/></a></li>
 </xsl:for-each>
    </ul>
  </xsl:if>
</xsl:template>
</xsl:stylesheet>

Matt

is working on a reply...