Hi Christoph,

This should get you going - assuming $currentPage is the "City" node, you can use the following XSLT in a macro to get started:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:umb="urn:umbraco.library"
    exclude-result-prefixes="umb"
>

    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

    <xsl:param name="currentPage" />

    <xsl:template match="/">
        <xsl:apply-templates select="$currentPage" />
    </xsl:template>

    <!-- Template for $currentPage -->
    <xsl:template match="node[@nodeTypeAlias = 'City']">
        <h1><xsl:value-of select="@nodeName" /></h1>

        <h2>Management</h2>
        <ul>
            <xsl:apply-templates select="node[@nodeName = 'Employees']/node[@nodeName = 'Management']/node" />
        </ul>

        <h2>Administration</h2>
        <ul>
            <xsl:apply-templates select="node[@nodeName = 'Employees']/node[@nodeName = 'Administration']/node" />
        </ul>
    </xsl:template>

    <!-- Template for a single employee -->
    <xsl:template match="node[@nodeTypeAlias = 'Employee']">
        <li>
            <xsl:value-of select="@nodeName" />
        </li>
    </xsl:template>

</xsl:stylesheet>

(There's a couple of assumptions - e.g., that city nodes have an alias of "City" and that employee nodes have the alias "Employee", but you should be able to make the necessary changes yourself, if needed.) 

/Chriztian

is working on a reply...