The suggested solution is 'just a workaround' and doesn't actually solve the problem. Or rather, it creates another (less obvious) problem.

The real solution will be released as an updated package to XSLT shortly. But if you're in a hurry you can modify your existing XSLTsearch 2.8.1 (and 2.8.1 only) as follows to fix the multi-word search bug.

Add "/*" after GetXmlAll()

Search for GetXmlAll(). It only appears once. Change it as shown below.

 <!-- using ALL nodes -->
   <xsl:call-template name="search">
     <xsl:with-param name="items" select="umbraco.library:GetXmlAll()/*"/> <!-- DJR added /* to the end  -->
   </xsl:call-template>

Replace the booleanAndMatchedNodes template

The real problem lies in this template and its recursive xpath, and a few anciliary lines of code as well. Rather than noting each line that has changed, just replace the entire template with that shown here.

 <xsl:template name="booleanAndMatchedNodes">
    <xsl:param name="yetPossibleNodes"/>
    <xsl:param name="searchTermList"/>

    <xsl:variable name="searchTerm">
      <xsl:value-of select="ps:getFirstElement($searchTermList, ' ')"/>
    </xsl:variable>
    <xsl:variable name="remainingSearchTermList">
      <xsl:value-of select="ps:removeFirstElement($searchTermList, ' ')"/>
    </xsl:variable>

    <xsl:variable name="searchFieldsAttribsOnly">
      <xsl:variable name="sf" select="umbraco.library:Split($searchFields, ',')" />
      <xsl:for-each select="$sf//value">
        <xsl:if test="substring(., 1, 1) = '@'">
          <xsl:text>,</xsl:text>
          <xsl:value-of select="substring-after(., '@') "/>
          <xsl:text>,</xsl:text>
        </xsl:if>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="attribNodes" select="$yetPossibleNodes[@isDoc 
                                                  and attribute::*[
                                                          contains($searchFieldsAttribsOnly,concat(',', name(), ','))
                                                          and contains(ps:uppercase(umbraco.library:StripHtml(string(.))), $searchTerm)
                                                          ]
                                                  ]" />

    <xsl:variable name="propertyNodes" select="$yetPossibleNodes/*[count(@isDoc) = 0 
                                                  and contains($searchFields,concat(',', name(), ','))
                                                  and contains(ps:uppercase(umbraco.library:StripHtml(string(.))), $searchTerm) 
                                                  ]/.." />

    <xsl:variable name="evenYetPossibleNodes" select="$attribNodes | $propertyNodes" />

    <xsl:choose>
      <xsl:when test="string-length($remainingSearchTermList) &gt; 1">
        <!-- continue to search the rest of the terms -->
        <xsl:call-template name="booleanAndMatchedNodes">
          <xsl:with-param name="yetPossibleNodes" select="$evenYetPossibleNodes"/>
          <xsl:with-param name="searchTermList" select="$remainingSearchTermList"/>
        </xsl:call-template>
      </xsl:when>
      
      <xsl:otherwise>
        <!-- finished searching: return a list of the attribute @id's of the currently possible nodes as the final set of matched nodes -->
        <xsl:variable name="nodeIDList">
          <xsl:text>;</xsl:text>
          <xsl:for-each select="$evenYetPossibleNodes">
            <!-- @id for this node -->
            <xsl:choose>
              <xsl:when test="@isDoc">
                <xsl:value-of select="@id"/>
              </xsl:when>
              <xsl:otherwise>
                <xsl:value-of select="../@id"/>
              </xsl:otherwise>
            </xsl:choose>
            <xsl:text>;</xsl:text>
          </xsl:for-each>
        </xsl:variable>

        <!-- return the actual list of id's -->
        <xsl:value-of select="$nodeIDList"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

These fixes will appear in XSLTsearch 2.8.2 and all subsequent versions. I have a number of other fixes to implement and may skip 2.8.2 and may jump right to the 2.9 or 3.0 release. But as I say, all future releases will have this fix for multiple word searches.

cheers, and my apologies for the bug in the first place,
doug.